Microphone.setUseEchoSuppression()

Доступность

Flash Player 6.

Синтаксис

active_mic.setUseEchoSuppression(suppress:Boolean) : Void

Параметры

suppress Булева величина, показывающая, используется (true) или не используется (false) возможность эхокомпенсации.

Возвращает

Ничего.

Описание

Метод; определяет, используется ли возможность эхокомпенсации аудио кодеком. Значение по умолчанию — false, пока пользователь не выберет Reduce Echo на панели Flash Player Microphone Settings.

Эхокомпенсация используется для избавления от эффекта зацикливания звука, происходящего, когда звук из колонок улавливается микрофоном на том же самом компьютере. (Оно отличается от эхоподавления, устраняющего этот эффект полностью.)

В общем случае, эхокомпенсацию рекомендуется использовать, когда захватываемый звук идет из колонок — а не наушников — на том же самом компьютере. Если ваш SWF позволяет пользователю выбрать устройство вывода звука, Вы можете захотеть вызвать Microphone.setUseEchoSuppression(true), если пользователь использует одновременно микрофон для захвата и колонки для вывода звука.

Эти настройки также доступны на панели Flash Player Microphone Settings.

Пример

В примере ниже эхокомпенсация включается, если пользователь отмечает компонент CheckBox с именем useEchoSuppression_ch. Компонент ProgressBar с именем activityLevel_pb отображает уровень активности аудиопотока.

var useEchoSuppression_ch:mx.controls.CheckBox;
var activityLevel_pb:mx.controls.ProgressBar;

this.createEmptyMovieClip("sound_mc", this.getNextHighestDepth());
var active_mic:Microphone = Microphone.get();
sound_mc.attachAudio(active_mic);

activityLevel_pb.mode = "manual";
activityLevel_pb.label = "Уровень активности: %3";
useEchoSuppression_ch.selected = active_mic.useEchoSuppression;
this.onEnterFrame = function() {
  activityLevel_pb.setProgress(active_mic.activityLevel, 100);
};
var chListener:Object = new Object();
chListener.click = function (evt:Object) {
  active_mic.setUseEchoSuppression(evt.target.selected);
};
useEchoSuppression_ch.addEventListener("click", chListener);

См. также

Microphone.setGain(), Microphone.useEchoSuppression

Посмотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление